Опис файлу

Gnuplot

# Author: Ika, 2013-07-24
set term svg size 800,600 enhanced font 'Times,12'
set output 'Second_Order_Taylor.svg'

set multiplot

set xlabel "x"
set ylabel "y"
set zlabel "z"
set xrange [-1.0:2.0]
set yrange [-0.5:2.0]
set zrange [-6.0:10.0]
set box
unset colorbox
#set view 65,45
set style fill solid 0.30 border

set cntrparam levels auto 20
set contour base
set isosamples 60,60
set samples 60,60
set pm3d
set hidd
unset key
set ticslevel 0
i = {0.0,1.0}

# Draw the surface of f(x,y) = e^x log(1+y)
set palette defined (-1 "blue", 1 "pink")
splot exp(x)*log(1+y)

# Draw the surface of f(x,y) = y+xy-y^2/2
set palette defined (-1 "red", 1 "orange")
splot y+x*y-y*y/2

# Draw the lines
unset cntrparam
unset contour
set isosamples 20,20
set samples 20,20
unset pm3d
unset hidd

# Draw the lines of f(x,y) = e^x log(1+y)
splot exp(x)*log(1+y) lt 2 lc rgb "black" lw 0.1

# Draw the lines of f(x,y) = y+xy-y^2/2
splot y+x*y-y*y/2 lt 2 lc rgb "black" lw 0.1

unset multiplot
set term x11
set output

Ліцензування

Я, власник авторських прав на цей твір, добровільно публікую його на умовах такої ліцензії:

Цей файл ліцензований на умовах Creative Commons Attribution-Share Alike 3.0 Unported

Ви можете вільно:

• ділитися – копіювати, поширювати і передавати твір
• модифікувати – переробляти твір

При дотриманні таких умов:

• зазначення авторства – Ви повинні вказати авторство, надати посилання на ліцензію і вказати, чи якісь зміни було внесено до оригінального твору. Ви можете зробити це в будь-який розсудливий спосіб, але так, щоб він жодним чином не натякав на те, наче ліцензіар підтримує Вас чи Ваш спосіб використання твору.
• поширення на тих же умовах – Якщо ви змінюєте, перетворюєте або створюєте іншу похідну роботу на основі цього твору, ви можете поширювати отриманий у результаті твір тільки на умовах такої ж або сумісної ліцензії.

https://creativecommons.org/licenses/by-sa/3.0CC BY-SA 3.0 Creative Commons Attribution-Share Alike 3.0 truetrue